!include "MUI2.nsh"
!include "LogicLib.nsh"
!include "nsDialogs.nsh"
!include "WinMessages.nsh"

!ifndef BUILD_UNINSTALLER
Var ChjGuidanceDialog
Var ChjGuidanceText
Var ChjGuidanceFile
Var ChjGuidanceLine

LangString ChjGuidanceTitle 1029 "Provozní bezpečnost a zálohování"
LangString ChjGuidanceTitle 1031 "Betriebssicherheit und Datensicherung"
LangString ChjGuidanceTitle 1033 "Operational safety and backups"
LangString ChjGuidanceNote 1029 "Informativní a nezávazné pokyny. Další krok zobrazí licenci; souhlas se týká pouze licence."
LangString ChjGuidanceNote 1031 "Informative, unverbindliche Hinweise. Danach folgt die Lizenz; nur diese erfordert Zustimmung."
LangString ChjGuidanceNote 1033 "Informational, non-binding guidance. The license follows; agreement applies only to the license."

!macro customWelcomePage
  Page custom ChjGuidanceCreate
!macroend

Function ChjGuidanceCreate
  !insertmacro MUI_HEADER_TEXT "$(ChjGuidanceTitle)" "$(ChjGuidanceNote)"
  nsDialogs::Create 1018
  Pop $ChjGuidanceDialog
  ${If} $ChjGuidanceDialog == error
    Quit
  ${EndIf}
  ${NSD_CreateLabel} 0 0 100% 24u "$(ChjGuidanceNote)"
  Pop $0
  nsDialogs::CreateControl "EDIT" ${WS_CHILD}|${WS_VISIBLE}|${WS_TABSTOP}|${WS_VSCROLL}|${ES_MULTILINE}|${ES_READONLY}|${ES_AUTOVSCROLL} ${WS_EX_CLIENTEDGE} 0 26u 100% 110u ""
  Pop $ChjGuidanceText
  SendMessage $ChjGuidanceText ${EM_SETLIMITTEXT} 65535 0
  InitPluginsDir
  File /oname=$PLUGINSDIR\chj-guidance-cs.txt "${BUILD_RESOURCES_DIR}\guidance-cs.txt"
  File /oname=$PLUGINSDIR\chj-guidance-de.txt "${BUILD_RESOURCES_DIR}\guidance-de.txt"
  File /oname=$PLUGINSDIR\chj-guidance-en.txt "${BUILD_RESOURCES_DIR}\guidance-en.txt"
  ${If} $LANGUAGE == 1029
    FileOpen $ChjGuidanceFile "$PLUGINSDIR\chj-guidance-cs.txt" r
  ${ElseIf} $LANGUAGE == 1031
    FileOpen $ChjGuidanceFile "$PLUGINSDIR\chj-guidance-de.txt" r
  ${Else}
    FileOpen $ChjGuidanceFile "$PLUGINSDIR\chj-guidance-en.txt" r
  ${EndIf}
  ${If} ${Errors}
    Quit
  ${EndIf}
  FileSeek $ChjGuidanceFile 2 SET
  chj_guidance_read:
    ClearErrors
    FileReadUTF16LE $ChjGuidanceFile $ChjGuidanceLine
    IfErrors chj_guidance_done
    SendMessage $ChjGuidanceText ${EM_REPLACESEL} 0 "STR:$ChjGuidanceLine"
    Goto chj_guidance_read
  chj_guidance_done:
    FileClose $ChjGuidanceFile
    SendMessage $ChjGuidanceText ${EM_SETSEL} 0 0
    SendMessage $ChjGuidanceText ${EM_SCROLLCARET} 0 0
    nsDialogs::Show
FunctionEnd
!endif